[사무자동화산업기사 실기] 조건 합 (SUMPRODUCT 이용)

사무자동화산업기사 실기 (OA산기 실기)
작업 과정	1부 완성본	합격 후기
공개문제 완성본
액셀	액세스	파워포인트
보충 수업
엑셀 함수	엑셀 조건 합 (SUMPRODUCT)	엑셀 조건 평균 (SUMIF, COUNTIF)
액세스 쿼리

 

 

사무자동화산업기사 엑셀에 자주 나오는 조건에 맞는 합계를 정리했습니다.

SUMPRODUCT 함수를 이용해서 문제를 푸는 법입니다.

 

 

1. 관련 함수

1. 수학 / 삼각 함수

SUMPRODUCT: 배열1과 배열2를 곱하고, 결과 합

SUMIFS: 여러 조건에 맞는 합계

 

2. 텍스트 함수

FIND: '찾을 텍스트'를 '문자열'에서 찾아 '찾을 텍스트'의 시작 위치를 반환

 

3. 정보 함수

ISNUMBER: 숫자 있는 셀 판별 

 

 

2. 푸는 법

1. SUMPRODUCT 사용
2. SUMPRODUCT, ISNUMBER, FIND 사용
3. SUMIFS 사용

 

 

 

1부)

 

예제 1. 단가가 20000 이상 30000 미만인 제품들의 주문량 합

1) SUMPRODUCT 사용

=SUMPRODUCT(($B$4:$B$23>=20000)*($B$4:$B$23<30000),F4:F23)

 

2) SUMIFS 사용

=SUMIFS(F4:F23,$B$4:$B$23,">=20000",$B$4:$B$23,"<30000")

 

 

 

문제 1)

 

예제 1.전자은행과 거래하는 고객들 중 성별이 남성인 고객의 대출가능액의 합

1) SUMPRODUCT 사용

=SUMPRODUCT((B5:B19="전자은행") * (D5:D19="남성"), G5:G19)

 

2) SUMPRODUCT, ISNUMBER, FIND 사용

=SUMPRODUCT(ISNUMBER(FIND("전자은행",B5:B19)) * ISNUMBER(FIND("남성",D5:D19)), G5:G19)

 

3) SUMIFS 사용

=SUMIFS(G5:G19, B5:B19,"전자은행",D5:D19,"남성")

 

 

예제 2. 성별이 남성이고 성이 이씨이면서 비자은행과 거래하는 고객의 대출이자의 합

1) SUMPRODUCT 사용

=SUMPRODUCT((D5:D19="남성") * (LEFT(C5:C19,1)="이") * (B5:B19="비자은행"), F5:F19)

 

2) SUMPRODUCT, ISNUMBER, FIND 사용

=SUMPRODUCT(ISNUMBER(FIND("남성",D5:D19)) * ISNUMBER(FIND(LEFT(C5:C19,1),"이")) * ISNUMBER(FIND("비자은행",B5:B19)), F5:F19)

 

3) SUMIFS 사용

=SUMIFS(F5:F19, $D$5:$D$19,"남성",$C$5:$C$19,"이*",$B$5:$B$19,"비자은행")

 

 

문제 2) 

 

예제 1. 성이 김씨 또는 이씨이면서 라면을 주문한 금액의 합

// 같은 기준에서 조건이 2개 들어가는 경우

 

1) SUMPRODUCT 사용

=SUMPRODUCT(((LEFT(C5:C21,1)="김") + (LEFT(C5:C21,1)="이")) * (B5:B21="라면"), H5:H21)

 

2) SUMPRODUCT, ISNUMBER, FIND 사용

=SUMPRODUCT(((LEFT($C$5:$C$21,1)="김")+(LEFT($C$5:$C$21,1)="이"))*ISNUMBER(FIND("라면",$B$5:$B$21)), H5:H21)

 

3) SUMIFS 사용

=SUMIFS(H5:H21,C5:C21,"김*",B5:B21,"라면") + SUMIFS(H5:H21,C5:C21,"이*",B5:B21,"라면")